[NTG-context] new (lmtx) beta

Hans Hagen j.hagen at xs4all.nl
Fri Oct 4 18:10:54 CEST 2019


Hi,

I uploaded a new lmtx beta. Again some more metafun trickery (see 
luametafun manual). I attached an (lmtx only) example of some experiment 
code, dedicated to Alan Braslau (teacher among other things).

Hans

-----------------------------------------------------------------
                                           Hans Hagen | PRAGMA ADE
               Ridderstraat 27 | 8061 GH Hasselt | The Netherlands
        tel: 038 477 53 69 | www.pragma-ade.nl | www.pragma-pod.nl
-----------------------------------------------------------------
-------------- next part --------------
A non-text attachment was scrubbed...
Name: kindergarten.pdf
Type: application/pdf
Size: 9795 bytes
Desc: not available
URL: <http://mailman.ntg.nl/pipermail/ntg-context/attachments/20191004/deb3d155/attachment.pdf>
-------------- next part --------------
\startMPcalculation{simplefun}

    pen KindergartenPen ; KindergartenPen := pencircle scaled 1 ;

    % 10 x 10 grid

    vardef KindergartenEqual =
        draw image
            (
                draw (2,6) -- (9,5) ;
                draw (2,4) -- (8,3) ;
            )
            shifted (0,-2)
            withpen KindergartenPen
            withcolor "KindergartenEqual"
    enddef ;
    vardef KindergartenPlus =
        draw image
            (
                draw (1,4) -- (9,5) ;
                draw (4,1) -- (5,8) ;
            )
            shifted (0,-2)
            withpen KindergartenPen
            withcolor "KindergartenPlus"
    enddef ;
    vardef KindergartenMinus =
        draw image
            (
                draw (1,5) -- (9,4) ;
            )
            shifted (0,-2)
            withpen KindergartenPen
            withcolor "KindergartenMinus"
    enddef ;
    vardef KindergartenTimes =
        draw image
            (
                draw (2,1) -- (9,8) ;
                draw (8,1) -- (2,8) ;
            )
            shifted (0,-2)
            withpen KindergartenPen
            withcolor "KindergartenTimes"
    enddef ;
    vardef KindergartenDivided =
        draw image
            (
                draw (2,1) -- (8,9) ;
            )
            shifted (0,-2)
            withpen KindergartenPen
            withcolor "KindergartenDivided"
    enddef ;

    lmt_registerglyphs [
        name     = "kindergarten",
        units    = 10,
      % usecolor = true,
        width    = 10,
        height   = 8,
        depth    = 2,
    ] ;

    lmt_registerglyph [ category = "kindergarten", unicode = "0x003D",
        code = "KindergartenEqual"
    ] ;
    lmt_registerglyph [ category = "kindergarten", unicode = "0x002B",
        code = "KindergartenPlus"
    ] ;
    lmt_registerglyph [ category = "kindergarten", unicode = "0x2212",
        code = "KindergartenMinus"
    ] ;
    lmt_registerglyph [ category = "kindergarten", unicode = "0x00D7",
        code = "KindergartenTimes"
    ] ;
    lmt_registerglyph [ category = "kindergarten", unicode = "0x002F",
        code = "KindergartenDivided"
    ] ;

\stopMPcalculation

\definecolor[KindergartenEqual]  [darkgreen]
\definecolor[KindergartenPlus]   [darkred]
\definecolor[KindergartenMinus]  [darkred]
\definecolor[KindergartenTimes]  [darkblue]
\definecolor[KindergartenDivided][darkblue]

\definefontfeature
  [mathextra]
  [metapost=kindergarten]

\setupbodyfont[dejavu]

\startTEXpage[offset=10pt]
    $ y = 2 \times x + a - b / 3 $ \par
    \hfill \infofont{kindergarten math}
\stopTEXpage


More information about the ntg-context mailing list