# [NTG-context] About the macro path intersectionpoint path with Metapost

Fabrice L fabrice.alpha at gmail.com
Mon Feb 4 15:16:21 CET 2019

```Hi,

I guess your problem is to find the two points of intersection between p
and r ? If so, the problem is that intersectionpoint does return the same
intersection when there is several, as it is the case here. So a quick
solution that you can do is to find intersections for the two part. A
drawing is simple than words ! here is the code to illustrate:

Happy drawing !
F.

\setupcolors[state=start]
\starttext
\startMPpage
path p, q, r, b , u;
p:= fullcircle scaled 6cm ;
q:= fullcircle scaled 4cm shifted (2.5cm,2cm) ;
r:= fullcircle scaled 4cm shifted (-2.5cm,2cm);
b:= fullcircle scaled 2cm shifted (0,-3cm);
pair A, B ;
path rprime ;
% Rprime is a a part of r (drawn in black to see it):
rprime := r cutbefore point .5 along r;
A:= p intersectionpoint r ;
B:= p intersectionpoint rprime ;
draw A withpen pencircle scaled .1in ;
draw B withpen pencircle scaled .1in ;

u:= A--B--cycle ;
draw p withcolor green;
draw q withcolor blue;
draw rprime  withpen pencircle scaled .05in withcolor black;
draw r withcolor red;
draw b withcolor magenta;
draw u numberstriped (.25,15,5) withcolor magenta ;
\stopMPpage
\stoptext

Le 3 février 2019 à 06:28:37, Fabrice Couvreur (fabrice1.couvreur at gmail.com)
a écrit:

Hi,
I would like to reproduce the attached figure. My problem is to create the
points of intersection between the circles. It seems that my approach is
not the right one.
Thank you.
Fabrice

\starttext
\startMPcode
path p, q, r, b ;
p:= fullcircle scaled 6cm ;
q:= fullcircle scaled 4cm shifted (2.5cm,2cm) ;
r:= fullcircle scaled 4cm shifted (-2.5cm,2cm);
b:= fullcircle scaled 2cm shifted (0,-3cm);
pair A, B ;
A:= p intersectionpoint r ;
B:= p intersectionpoint r ;
path u ;
u:= A--B--cycle ;
draw p ;
draw q ;
draw r ;
draw b ;
draw u numberstriped (.25,15,5) withcolor magenta ;
\stopMPcode
\stoptext
___________________________________________________________________________________
the Wiki!

maillist : ntg-context at ntg.nl /
http://www.ntg.nl/mailman/listinfo/ntg-context